F4if_int_table_value_request

[zonanet]

Saludos a todos!!!

Sabrán si la función F4IF_INT_TABLE_VALUE_REQUEST podrá regresar dos parametros export???

gracias por la ayuda.

[DavidXD_XD]

Hola Zonanet, pues si, si puedes regresar 2 parametros, pero solo escogerias uno solo, de casualidad lo que quieres es seleccionar un registro de la ayuda de busqueda y cuando clickees en el que quieres se actualizen 2 campos de tu pantalla?

[zonanet]

Buen día David!

Es eso mismo, necesito actualizar dos campos en pantalla, sólo tomando uno de la ayuda, como lo estoy haciendo nada más regresa un campo.


Gracias por la ayuda que me puedas brindar.

[DavidXD_XD]

Aver te pongo un ejemplo de como mas o menos sale ... yo tengo un campo pais (ZZT_MST_TRAB-PAICO), el cual le agrego un matchcode, pero cuando selecciono el pais se actualiza el campo pais y a su costado se actualiza el campo descripcion (G_DESPAIS)

MODULE get_val_pais INPUT.

DATA: gt_nacion TYPE TABLE OF ty_nacion.

SELECT paico despa
INTO TABLE gt_nacion
FROM zztnacion.

CLEAR: ti_match, ti_match[].

CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
EXPORTING
retfield = 'PAICO'
dynpprog = sy-repid
dynpnr = sy-dynnr
dynprofield = 'ZZT_MST_TRAB-PAICO'
value_org = 'S'
TABLES
value_tab = gt_nacion
return_tab = ti_match
EXCEPTIONS
PARAMETER_ERROR = 1
NO_VALUES_FOUND = 2
OTHERS = 3.

IF sy-subrc <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.

READ TABLE ti_match INDEX 1 INTO g_wa_match.

SELECT SINGLE despa
INTO g_despais
FROM zztnacion
WHERE paico EQ g_wa_match-fieldval.

CLEAR ti_dynfields.
g_wa_dynfields-fieldname = 'ZZT_MST_TRAB-PAICO'.
g_wa_dynfields-fieldvalue = g_wa_match-fieldval.
g_wa_dynfields-stepl = 0.
APPEND g_wa_dynfields TO ti_dynfields.

g_wa_dynfields-fieldname = 'G_DESPAIS'.
g_wa_dynfields-fieldvalue = g_despais.
g_wa_dynfields-stepl = 0.
APPEND g_wa_dynfields TO ti_dynfields.

* Actualizamos los campos del dynpro 210.
CALL FUNCTION 'DYNP_VALUES_UPDATE'
EXPORTING
DYNAME = SY-CPROG
DYNUMB = SY-DYNNR
TABLES
DYNPFIELDS = ti_dynfields[].

IF SY-SUBRC <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.

ENDMODULE. " get_val_pais INPUT

Espero q este ejemplo pueda ayudarte :D